package bdd
{
	import flash.data.SQLConnection;
	import flash.data.SQLResult;
	import flash.data.SQLStatement;
	import flash.filesystem.File;
 
	public class MySqlLite extends SQLConnection
	{
		protected var fichier:File;
 
		// Pattern Singleton c'est mieux.
		private static var instance:MySqlLite
 
		public function MySqlLite(access:Singleton)
		{
			super();
 
			// Initilisation de la base. Création des tables si besoin est.
			init();
		}
 
		// Implémentation du singleton.
		public static function getInstance():MySqlLite{
			if(instance == null){
				instance = new MySqlLite(new Singleton());
			}
			return instance;
		}		
 
		public function init():void
		{
			// Autant se créer notre fichier BDD dans le répertoire d'installation de notre Application non ?
			fichier = new File(File.applicationDirectory.nativePath + "/Sports2009-bdd.bd")
 
			// Si le fichier n'existe pas déjà, on crée nos tables !
			if(!fichier.exists)
			{
				this.open(fichier);
				var stmt:SQLStatement = new SQLStatement();
				stmt.sqlConnection = this;
				stmt.text = "CREATE TABLE performances (id INTEGER PRIMARY KEY AUTOINCREMENT, creation_date DateTime, calorie decimal, kilometre decimal, temps decimal)";
				// Hop insertion de notre 1er table
				stmt.execute();	
 
				// Notre Statement est chaud bouillant pour créer une deuxième table, soyons fou.
				stmt.text = "CREATE TABLE utilisateur (id INTEGER PRIMARY KEY AUTOINCREMENT, nom longvarchar, password longvarchar)";
				stmt.execute();
			}
			else
			{
				// Le fichier existe, on ouvre notre bdd :)
				this.open(fichier);
			}
		}
 
		// On peut explicitement fermer la bdd ..
		public function fermer():void
		{
			this.close();
		}
 
		// Exécutons notre requete SQL et retournons le résultat :)
		public function requete(maRequeteSql:String):SQLResult
		{
			var requete:SQLStatement = new SQLStatement();
			requete.sqlConnection =this;
			requete.text = maRequeteSql
			requete.execute();
 
			// On récupère le résultat de l'execution
			var r:SQLResult = new SQLResult()		
 
			// ATTENTION on ne peut faire qu'un seul getResult()
			// Pourquoi ? car c'est à usage unique
			// une fois que l'on a demandé des infos "pssshhtt ça disparait !"
			r =  requete.getResult();
			return r;
		}
 
	}
}
 
class Singleton{
	public function Singleton()
	{
 
	}
}

package users
{
	import bdd.MySqlLite;
	import flash.data.SQLResult;
	import flash.data.SQLStatement;
 
	public class Utilisateur extends Object
	{
 
		private var name:String;
		private var password:String;
 
		public function Utilisateur(nom:String,pass:String)
		{
			super();
			this.setName(nom);
			this.setPassword(pass);
		}
 
		public function getName():String
		{
			return this.name;
		}
 
		public function getPassword():String
		{
			return this.password;
		}
 
		public function setName(nom:String):void
		{
			this.name= nom;
		}
 
		public function setPassword(pass:String):void
		{
			this.password = pass;
		}
 
		// Test voir si le gugus existe
		public function existe():Boolean
		{
			var test:SQLResult = new SQLResult();
			test = MySqlLite.getInstance().requete("SELECT * from utilisateur WHERE nom='" + this.name +"' and password='" + this.password +"' ");
			return test.data != null
		}
 
		// Inscription du gugus
		public function inscription():Boolean
		{
			if(!existe())
			{
				var test:SQLResult = new SQLResult();
				test = MySqlLite.getInstance().requete("INSERT INTO utilisateur (nom,password) VALUES ('" + this.name +"','" + this.password +"') ");
				return true;
			}
			else
			{
				return false;
			}
		}
 
	}
}

public function TestConnexion(e:ConnexionEvent):void
{
	var user:Utilisateur = new Utilisateur(e.sLogin,e.sPassword)
	if(user.existe())
	{
		pannelConnexion.currentState = "OK"
		this.currentState = "Dashboard";
	}
	else
	{
		pannelConnexion.currentState = "Erreur"
	}
}
 
public function Inscription(e:ConnexionEvent):void
{
	var user:Utilisateur = new Utilisateur(e.sLogin,e.sPassword)
	if(user.inscription())
	{
		trace("je me suis bien inscrit");
	}
	else
	{
		trace("j'existe déjà ...");
	}
}

package Event
{
	import flash.events.Event;
 
	public class ConnexionEvent extends Event
	{
		public var sLogin:String;
		public var sPassword:String;
 
		public function ConnexionEvent(type:String,login:String,password:String, bubbles:Boolean=false, cancelable:Boolean=false)
		{
			super(type, bubbles, cancelable);
			sLogin = login;
			sPassword = password;
		}
 
	}
}